VB.NET, C#, PowerShell Tipsサイト

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    ComboBox1.DrawMode = DrawMode.OwnerDrawFixed

    'InstalledFontCollectionオブジェクトの取得
    Dim InstalledFont As New System.Drawing.Text.InstalledFontCollection

    'インストール済みフォントを取得してコンボボックスに表示する
    Dim FontFamilies As FontFamily() = InstalledFont.Families
    For Each f As FontFamily In FontFamilies
        ComboBox1.Items.Add(f.Name)
    Next f
End Sub

Private Sub ComboBox1_DrawItem(ByVal sender As Object, ByVal e As System.Windows.Forms.DrawItemEventArgs) _
    Handles ComboBox1.DrawItem

    Dim FontF As FontFamily
    Dim fnt As Font
    Dim fs As FontStyle

    '現在のインデックスのフォントファミリを取得
    FontF = New FontFamily(ComboBox1.Items.Item(e.Index).ToString)

    'フォントによってはFontStyle.Regularをサポートしていない場合があるので
    '描画するフォントのスタイルを取得しておく
    If FontF.IsStyleAvailable(FontStyle.Regular) Then
        fs = FontStyle.Regular
    ElseIf FontF.IsStyleAvailable(FontStyle.Italic) Then
        fs = FontStyle.Italic
    Else
        fs = FontStyle.Bold
    End If

    '取得しておいたフォントスタイルを使用してフォントを作成
    fnt = New Font(FontF, 9, fs)

    '適切な色で背景を描画
    e.DrawBackground()

    e.Graphics.DrawString( _
        ComboBox1.Items.Item(e.Index).ToString, _
        fnt, _
        New SolidBrush(Color.Black), _
        e.Bounds.X, _
        e.Bounds.Y)

    'フォントの破棄
    fnt.Dispose()
    FontF.Dispose()
End Sub